Windows 8’de varmıydı hatırlamıyorum ama Windows 10’da kıl olduğum bir durum One Drive. Kullanmıyorum ama sürekli kendini başlatıyor ve bazen ekrana oturum açma sayfası geliyor. Sizde bu durumdan şikayetciyseniz aşağıdaki adımlardan birini tercih ederek onu kapatabilir veya tamamen sistemden kaldırabilirsiniz.

 One Drive’ı Kapatmak:

Hani olurda ileride tekrar açıp kullanmak isterseniz tamamen silmek yerine kapatma seçeneği size cazip gelebilir. Sistem saatinin oradaki ok işaretinden One Drive simgesinde sağ tıklar, Ayarlar‘a tıklarsınız.

 

Ardından One Drive Ayarlar sekmesindeWindows’ta oturum açtığımda One Drive’ı otomatik olarak başlat” seçeneğinin yanındaki tiki kaldırıp, tamam butonuna tıklarsınız.

 

 Artık bilgisayar açıldığında One Drive otomatik başlamayacağından sinir eden oturum açma ekranı karşınıza gelmez.

One Drive’ı Tamamen Kaldırmak: 

Benim ne işim olur One Drive ile?” diyenlerdenseniz, aşağıdaki tüm komutları kaldir.bat uzantılı bir not defteri belgesine kaydeder, sonrasında bu belgeyi çalıştırırsınız. Otomatik olarak One Drive kaldırılır ve bir daha karşınıza gelmez.

 

@echo off
cls
set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"
echo Closing OneDrive process.
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1
echo Uninstalling OneDrive.
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1
echo Removing OneDrive leftovers.
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 
echo Removing OneDrive from the Explorer Side Panel.
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
pause

 

Not: Kaldir.bat dosyası oluşturmak için yukarıdaki komutları yeni bir not defteri belgesine yapıştırın, kaydet diyerek adını kaldir.txt olarak kayıt edin. Ardından windows gezgininden dosya uzantılarını açarak txt uzantısını bat olarak değiştirin. Uygulama Windows 10 Home 64 bit ve Windows 10 Pro 64 bit’de denenmiştir.

Alıntıdır: Kaynak